Improve android_support_tests.bzl

Adds a custom provider subject for `JavaInfo` and the test now reads better and reports more helpful failure messages. This will also ease migrating more java rules tests out of the Bazel codebase.

PiperOrigin-RevId: 721338635
Change-Id: I36269cf04de67698bbf3be3bec9507d12a55d895

Author: hvadehra

java/test/private/BUILD

@@ -11,24 +11,6 @@
 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 # See the License for the specific language governing permissions and
 # limitations under the License.
-
-load("//java:defs.bzl", "java_library", "java_plugin")
-load(":android_support_tests.bzl", "android_support_tests", "my_rule")
-
-java_plugin(
-    name = "my_plugin",
-    srcs = ["MyPlugin.java"],
-)
-
-java_library(
-    name = "foo",
-    srcs = ["Foo.java"],
-    exported_plugins = [":my_plugin"],
-)
-
-my_rule(
-    name = "bar",
-    dep = ":foo",
-)
+load(":android_support_tests.bzl", "android_support_tests")
 
 android_support_tests(name = "android_support_tests")

java/test/private/Foo.java

@@ -14,8 +14,11 @@
 """Tests for //java/private:android_support.bzl"""
 
 load("@rules_testing//lib:analysis_test.bzl", "analysis_test", "test_suite")
+load("@rules_testing//lib:util.bzl", "util")
+load("//java:defs.bzl", "java_library", "java_plugin")
 load("//java/common:java_info.bzl", "JavaInfo")
 load("//java/private:android_support.bzl", "android_support")
+load("//java/test/testutil:java_info_subject.bzl", "java_info_subject")
 
 def _impl(ctx):
     return [
@@ -30,25 +33,38 @@ my_rule = rule(
 )
 
 def _test_enable_implicit_sourceless_deps_exports_compatibility(name):
+    util.helper_target(
+        java_plugin,
+        name = "my_plugin",
+        srcs = ["MyPlugin.java"],
+    )
+    util.helper_target(
+        java_library,
+        name = "base",
+        srcs = ["Foo.java"],
+        exported_plugins = [":my_plugin"],
+    )
+    util.helper_target(
+        my_rule,
+        name = "transformed",
+        dep = ":base",
+    )
+
     analysis_test(
         name = name,
         impl = _test_enable_implicit_sourceless_deps_exports_compatibility_impl,
         targets = {
-            "foo": Label(":foo"),
-            "bar": Label(":bar"),
+            "base": Label(":base"),
+            "transformed": Label(":transformed"),
         },
     )
 
 def _test_enable_implicit_sourceless_deps_exports_compatibility_impl(env, targets):
-    # TODO(hvd): write a ProviderSubject for JavaInfo
-    foo_javainfo = targets.foo[JavaInfo]
-    bar_javainfo = targets.bar[JavaInfo]
-    for attr in ["transitive_runtime_jars", "compile_jars", "transitive_compile_time_jars", "full_compile_jars", "_transitive_full_compile_time_jars", "_compile_time_java_dependencies"]:
-        env.expect.that_bool(getattr(foo_javainfo, attr) == getattr(bar_javainfo, attr)).equals(True)
-    env.expect.that_depset_of_files(foo_javainfo.plugins.processor_jars).contains_exactly([
-        "java/test/private/libmy_plugin.jar",
-    ])
-    env.expect.that_depset_of_files(bar_javainfo.plugins.processor_jars).contains_exactly([])
+    base_info = java_info_subject.from_target(env, targets.base)
+    transformed_info = java_info_subject.from_target(env, targets.transformed)
+    transformed_info.compilation_args().equals(base_info.compilation_args())
+    base_info.plugins().processor_jars().contains_exactly(["{package}/libmy_plugin.jar"])
+    transformed_info.plugins().processor_jars().contains_exactly([])
 
 def android_support_tests(name):
     test_suite(

java/test/private/MyPlugin.java

@@ -0,0 +1,67 @@
+"""A custom @rules_testing subject for the JavaInfo provider"""
+
+load("@rules_testing//lib:truth.bzl", "subjects", "truth")
+load("//java/common:java_info.bzl", "JavaInfo")
+
+def _new_java_info_subject(java_info, meta):
+    self = struct(actual = java_info, meta = meta.derive("JavaInfo"))
+    public = struct(
+        compilation_args = lambda: _new_java_compilation_args_subject(self.actual, self.meta),
+        plugins = lambda: _new_java_info_plugins_subject(self.actual, self.meta),
+    )
+    return public
+
+def _java_info_subject_from_target(env, target):
+    return _new_java_info_subject(target[JavaInfo], meta = truth.expect(env).meta.derive(
+        format_str_kwargs = {
+            "name": target.label.name,
+            "package": target.label.package,
+        },
+    ))
+
+def _new_java_compilation_args_subject(java_info, meta):
+    actual = struct(
+        transitive_runtime_jars = java_info.transitive_runtime_jars,
+        compile_jars = java_info.compile_jars,
+        transitive_compile_time_jars = java_info.transitive_compile_time_jars,
+        full_compile_jars = java_info.full_compile_jars,
+        _transitive_full_compile_time_jars = java_info._transitive_full_compile_time_jars,
+        _compile_time_java_dependencies = java_info._compile_time_java_dependencies,
+        _is_binary = getattr(java_info, "_is_binary", False),
+    )
+    self = struct(
+        actual = actual,
+        meta = meta,
+    )
+    return struct(
+        equals = lambda other: _java_compilation_args_equals(self, other),
+        self = self,
+        actual = actual,
+    )
+
+def _java_compilation_args_equals(self, other):
+    if self.actual == other.actual:
+        return
+    for attr in dir(other.actual):
+        other_attr = getattr(other.actual, attr)
+        this_attr = getattr(self.actual, attr)
+        if this_attr != other_attr:
+            self.meta.derive(attr).add_failure(
+                "expected: {}".format(other_attr),
+                "actual: {}".format(this_attr),
+            )
+
+def _new_java_info_plugins_subject(java_info, meta):
+    self = struct(
+        actual = java_info.plugins,
+        meta = meta.derive("plugins"),
+    )
+    public = struct(
+        processor_jars = lambda: subjects.depset_file(self.actual.processor_jars, meta = self.meta.derive("processor_jars")),
+    )
+    return public
+
+java_info_subject = struct(
+    new = _new_java_info_subject,
+    from_target = _java_info_subject_from_target,
+)